Update Win32 support; inc version to 1.3.0
[wimlib] / configure.ac
1 AC_INIT([wimlib], [1.3.0], [ebiggers3@gmail.com])
2 AC_CONFIG_SRCDIR([src/wim.c])
3 AC_CONFIG_MACRO_DIR([m4])
4 AC_CONFIG_AUX_DIR([build-aux])
5 AM_INIT_AUTOMAKE([-Wall -Werror subdir-objects])
6 AC_C_BIGENDIAN
7 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
8 LT_INIT
9 AC_CONFIG_HEADERS([config.h])
10 AC_CONFIG_FILES([Makefile
11                 doc/Doxyfile
12                 wimlib.pc
13                 doc/imagex.1
14                 doc/imagex-append.1
15                 doc/imagex-apply.1
16                 doc/imagex-capture.1
17                 doc/imagex-delete.1
18                 doc/imagex-dir.1
19                 doc/imagex-export.1
20                 doc/imagex-info.1
21                 doc/imagex-join.1
22                 doc/imagex-mount.1
23                 doc/imagex-mountrw.1
24                 doc/imagex-optimize.1
25                 doc/imagex-split.1
26                 doc/imagex-unmount.1
27                 doc/mkwinpeimg.1
28                 ])
29 AC_PROG_CC
30 AM_PROG_CC_C_O
31
32 AC_CHECK_FUNCS([utimensat lutimes utime flock])
33 AC_CHECK_HEADERS([endian.h byteswap.h sys/byteorder.h sys/endian.h \
34                   sys/param.h machine/endian.h alloca.h stdlib.h stdarg.h \
35                   errno.h attr/xattr.h utime.h sys/file.h])
36
37 AC_CHECK_MEMBER([struct stat.st_mtim],
38                 [AC_DEFINE([HAVE_STAT_NANOSECOND_PRECISION], [1],
39                           [Define to 1 if nanosecond precision timestamps are
40                            supported])],
41                 [],
42                 [[#include <sys/stat.h>]])
43
44 AM_ICONV
45 if test "x$am_cv_func_iconv" != "xyes"; then
46         AC_MSG_ERROR([Cannot find the iconv() function.
47         iconv() is used to convert between UTF-8 and UTF-16 encodings of WIM
48         filenames and XML data.  Wimlib cannot be compiled without it.  iconv()
49         is available in the latest version of glibc and sometimes in other
50         libraries.])
51 fi
52
53
54 AC_ARG_WITH(pkgconfigdir,
55             [  --with-pkgconfigdir=DIR      pkgconfig file in DIR @<:@LIBDIR/pkgconfig@:>@],
56             [pkgconfigdir=$withval],
57             [pkgconfigdir='${libdir}/pkgconfig'])
58 AC_SUBST(pkgconfigdir)
59
60 AC_CHECK_LIB([xml2], [xmlParseFile], [have_libxml=true],
61              [AC_MSG_ERROR(["cannot find libxml2"])])
62 LIBXML2_LDADD=`pkg-config libxml-2.0 --libs`
63 LIBXML2_CFLAGS=`pkg-config libxml-2.0 --cflags`
64 AC_SUBST([LIBXML2_LDADD], [$LIBXML2_LDADD])
65 AC_SUBST([LIBXML2_CFLAGS], [$LIBXML2_CFLAGS])
66
67 AC_MSG_CHECKING([whether to include debugging messages])
68 AC_ARG_ENABLE([debug],
69         AS_HELP_STRING([--enable-debug], [include lots of debugging messages]),
70         [ENABLE_DEBUG=$enableval],
71         [ENABLE_DEBUG=no]
72         )
73 AC_MSG_RESULT([$ENABLE_DEBUG])
74 if test "x$ENABLE_DEBUG" = "xyes"; then
75         AC_DEFINE([ENABLE_DEBUG], [1],
76                         [Define to 1 if including lots of debug messages.])
77 fi
78
79 AC_MSG_CHECKING([whether to include more debugging messages])
80 AC_ARG_ENABLE([more_debug],
81         AS_HELP_STRING([--enable-more-debug],
82                         [include even more debugging messages]),
83         [ENABLE_MORE_DEBUG=$enableval],
84         [ENABLE_MORE_DEBUG=no]
85         )
86 AC_MSG_RESULT([$ENABLE_MORE_DEBUG])
87 if test "x$ENABLE_MORE_DEBUG" = "xyes"; then
88         AC_DEFINE([ENABLE_MORE_DEBUG], [1],
89                         [Define to 1 if including even more debug messages.])
90 fi
91
92 AC_MSG_CHECKING([whether to include error messages])
93 AC_ARG_ENABLE([error_messages],
94         AS_HELP_STRING([--disable-error-messages],
95                         [do not compile in error messsages]),
96         [ENABLE_ERROR_MESSAGES=$enableval],
97         [ENABLE_ERROR_MESSAGES=yes]
98         )
99 AC_MSG_RESULT([$ENABLE_ERROR_MESSAGES])
100 if test "x$ENABLE_ERROR_MESSAGES" = "xyes"; then
101         AC_DEFINE([ENABLE_ERROR_MESSAGES], [1],
102                         [Define to 1 if including error messages])
103 fi
104
105 AC_MSG_CHECKING([whether to support custom memory allocation functions])
106 AC_ARG_ENABLE([custom_memory_allocator],
107         AS_HELP_STRING([--disable-custom-memory-allocator],
108                        [do not support the use of custom memory allocation
109                         functions]),
110         [ENABLE_CUSTOM_MEMORY_ALLOCATOR=$enableval],
111         [ENABLE_CUSTOM_MEMORY_ALLOCATOR=yes]
112         )
113 AC_MSG_RESULT([$ENABLE_CUSTOM_MEMORY_ALLOCATOR])
114 if test "x$ENABLE_CUSTOM_MEMORY_ALLOCATOR" = "xyes"; then
115         AC_DEFINE([ENABLE_CUSTOM_MEMORY_ALLOCATOR], [1],
116                 [Define to 1 if supporting custom memory allocation functions])
117 fi
118
119 AC_MSG_CHECKING([whether to include assertions])
120 AC_ARG_ENABLE([assertions],
121         AS_HELP_STRING([--disable-assertions], [do not include assertions]),
122         [ENABLE_ASSERTIONS=$enableval],
123         [ENABLE_ASSERTIONS=yes]
124         )
125 AC_MSG_RESULT([$ENABLE_ASSERTIONS])
126 if test "x$ENABLE_ASSERTIONS" = "xyes"; then
127         AC_DEFINE([ENABLE_ASSERTIONS], [1], [Define to 1 if including assertions.])
128 fi
129
130 AC_MSG_CHECKING([whether to include more assertions])
131 AC_ARG_ENABLE([more-assertions],
132         AS_HELP_STRING([--enable-more-assertions], [include even more assertions]),
133         [ENABLE_MORE_ASSERTIONS=$enableval],
134         [ENABLE_MORE_ASSERTIONS=no]
135         )
136 AC_MSG_RESULT([$ENABLE_MORE_ASSERTIONS])
137 if test "x$ENABLE_MORE_ASSERTIONS" = "xyes"; then
138         AC_DEFINE([ENABLE_MORE_ASSERTIONS], [1], [Define to 1 if including more assertions.])
139 fi
140
141
142 AC_MSG_CHECKING([whether to include compression verification])
143 AC_ARG_ENABLE([verify_compression],
144               AS_HELP_STRING([--disable-verify-compression], [disable
145                                 checking if blocks we compress can be correctly
146                                 decompressed]),
147         [ENABLE_VERIFY_COMPRESSION=$enableval],
148         [ENABLE_VERIFY_COMPRESSION=yes]
149         )
150 AC_MSG_RESULT([$ENABLE_VERIFY_COMPRESSION])
151 if test "x$ENABLE_VERIFY_COMPRESSION" = "xyes"; then
152         AC_DEFINE([ENABLE_VERIFY_COMPRESSION], [1], [Define to 1 to verify
153                    compressed data])
154 fi
155
156 AC_MSG_CHECKING([whether to include support for multi-threaded compression])
157 AC_ARG_ENABLE([multithreaded-compression],
158         AS_HELP_STRING([--disable-multithreaded-compression],
159                         [do not compile in the code for multi-threaded compression]),
160         [ENABLE_MULTITHREADED_COMPRESSION=$enableval],
161         [ENABLE_MULTITHREADED_COMPRESSION=yes]
162         )
163 AC_MSG_RESULT([$ENABLE_MULTITHREADED_COMPRESSION])
164 if test "x$ENABLE_MULTITHREADED_COMPRESSION" = "xyes"; then
165         AC_DEFINE([ENABLE_MULTITHREADED_COMPRESSION], [1],
166                         [Define to 1 if including support for multithreaded
167                          compression])
168         PTHREAD_LDADD="-lpthread"
169 else
170         PTHREAD_LDADD=""
171 fi
172 AC_SUBST([PTHREAD_LDADD], [$PTHREAD_LDADD])
173
174 case "$host" in
175         *-*-cygwin*)
176                 dnl -no-undefined is needed to build a DLL in a Cygwin environment.
177                 CYGWIN_EXTRA_LDFLAGS="-no-undefined"
178
179                 dnl -fvisibility=hidden should not be used in a Cygwin
180                 dnl  environment
181                 VISIBILITY_CFLAGS=""
182
183                 WITH_NTFS_3G_DEFAULT="no"
184                 WITH_FUSE_DEFAULT="no"
185                 ;;
186         *)
187                 CYGWIN_EXTRA_LDFLAGS=""
188                 VISIBILITY_CFLAGS="-fvisibility=hidden"
189                 WITH_NTFS_3G_DEFAULT="yes"
190                 WITH_FUSE_DEFAULT="yes"
191                 ;;
192 esac
193
194 AC_SUBST([CYGWIN_EXTRA_LDFLAGS], [$CYGWIN_EXTRA_LDFLAGS])
195 AC_SUBST([VISIBILITY_CFLAGS], [$VISIBILITY_CFLAGS])
196
197 AC_MSG_CHECKING([whether to include support for ntfs-3g])
198 AC_ARG_WITH([ntfs-3g],
199               AS_HELP_STRING([--without-ntfs-3g], [build without NTFS-3g.
200                               This will disable the ability to use NTFS-specific
201                               information when capturing or applying WIMs to a
202                               NTFS filesystem.]),
203         [WITH_NTFS_3G=$withval],
204         [WITH_NTFS_3G=$WITH_NTFS_3G_DEFAULT]
205         )
206 AC_MSG_RESULT([$WITH_NTFS_3G])
207 if test "x$WITH_NTFS_3G" = "xyes"; then
208         AC_DEFINE([WITH_NTFS_3G], [1], [Define to 1 to enable support for
209                    NTFS-specific information])
210
211         dnl This effectively checks for NTFS-3g 2011.4.12 or later
212         AC_CHECK_LIB([ntfs-3g], [ntfs_xattr_system_setxattr], [],
213                         [AC_MSG_ERROR([Cannot find libntfs-3g version 2011-4-12
214         or later. Without libntfs-3g, wimlib cannot include support for
215         capturing and applying WIMs on NTFS filesystems while preserving
216         NTFS-specific data such as security descriptors and alternate data
217         streams.  You should either install libntfs-3g, or configure with
218         --without-ntfs-3g to disable support for these NTFS-specific
219         features.])])
220         LIBNTFS_3G_LDADD="`pkg-config --libs libntfs-3g`"
221         LIBNTFS_3G_CFLAGS="`pkg-config --cflags libntfs-3g`"
222
223         dnl This checks for a NTFS-3g interface that was changed in the
224         dnl 2013.1.13 release
225         AC_CHECK_DECL([NTFS_MNT_RDONLY],
226                       [AC_DEFINE([HAVE_NTFS_MNT_RDONLY],
227                                  [1],
228                                  [Define to 1 if ntfs_mount() takes the flag NTFS_MNT_RDONLY])],
229                       ,
230                       [#include <ntfs-3g/volume.h>])
231 else
232         LIBNTFS_3G_LDADD=
233         LIBNTFS_3G_CFLAGS=
234 fi
235 AM_CONDITIONAL([WITH_NTFS_3G], [test "x$WITH_NTFS_3G" = "xyes"])
236
237 AC_SUBST([LIBNTFS_3G_LDADD], [$LIBNTFS_3G_LDADD])
238 AC_SUBST([LIBNTFS_3G_CFLAGS], [$LIBNTFS_3G_CFLAGS])
239
240 AC_MSG_CHECKING([whether to include support for mounting WIMs])
241 AC_ARG_WITH([fuse],
242                 AS_HELP_STRING([--without-fuse], [build without libfuse.
243                                         This will disable the ability to mount
244                                         WIM files.]),
245         [WITH_FUSE=$withval],
246         [WITH_FUSE=$WITH_FUSE_DEFAULT]
247         )
248 AC_MSG_RESULT([$WITH_FUSE])
249 if test "x$WITH_FUSE" = "xyes"; then
250         AC_DEFINE([WITH_FUSE], [1], [Define to 1 if using FUSE.])
251
252
253         AC_CHECK_LIB([fuse], [fuse_main_real], [have_fuse=true],
254                         [AC_MSG_ERROR([Cannot find libfuse.
255         Without libfuse, wimlib cannot include support for mounting WIMs.  You
256         should either install libfuse, or configure with --without-fuse to
257         disable support for mounting WIMs.])
258         ])
259         AC_CHECK_LIB([rt], [mq_open], [have_posix_mq=true],
260                      [AC_MSG_ERROR([Cannot find librt for POSIX message queue
261         functions.  Without these functions, wimlib cannot include support for
262         mounting WIMs.  You should either update your C library to a recent
263         version of glibc, or configure with --without-fuse to disable support
264         for mounting WIMs.])
265         ])
266         LIBFUSE_LDADD="`pkg-config --libs fuse` -lrt"
267         LIBFUSE_CFLAGS="`pkg-config --cflags fuse`"
268 else
269         LIBFUSE_LDADD=
270         LIBFUSE_CFLAGS=
271 fi
272 AM_CONDITIONAL([WITH_FUSE], [test "x$WITH_FUSE" = "xyes"])
273 AC_SUBST([LIBFUSE_LDADD], [$LIBFUSE_LDADD])
274 AC_SUBST([LIBFUSE_CFLAGS], [$LIBFUSE_CFLAGS])
275
276 ENABLE_XATTR=no
277 AC_ARG_ENABLE([xattr],
278         [AS_HELP_STRING([--enable-xattr], [Enable the xattr interface to access WIM
279                         alternate data streams (default: autodetect)])],
280         [ENABLE_XATTR=$enableval],
281         [AC_CHECK_FUNC([setxattr],
282                 [AC_CHECK_HEADER([attr/xattr.h],
283                         [ENABLE_XATTR=yes],
284                         [AC_MSG_WARN([Cannot find the "attr/xattr.h" header.  You will not be
285                          able to use the xattr interface to access WIM alternate data
286                          streams.])])],
287                 [AC_MSG_WARN([Cannot find the setxattr() function.  You will not be
288                  able to use the xattr interface to access WIM alternate data
289                  streams.])])])
290
291 if test "x$ENABLE_XATTR" = "xyes"; then
292         AC_DEFINE([ENABLE_XATTR], [1], [Define to 1 if using the xattr
293                         interface to WIM alternate data streams])
294 fi
295
296 AC_MSG_CHECKING([whether to use SSSE3-accelerated SHA1 ])
297 AC_ARG_ENABLE([ssse3-sha1],
298             AS_HELP_STRING([--enable-ssse3-sha1], [use assembly language implementation
299                                 of SHA1 from Intel, accelerated with vector
300                                 instructions (SSSE3-enabled CPU required)]),
301         [ENABLE_SSSE3_SHA1=$enableval],
302         [ENABLE_SSSE3_SHA1=no]
303         )
304
305 AC_MSG_RESULT([$ENABLE_SSSE3_SHA1])
306 if test "x$ENABLE_SSSE3_SHA1" = "xyes"; then
307         AC_DEFINE([ENABLE_SSSE3_SHA1], [1],
308                         [Define to 1 if using vectorized implementation of SHA1])
309         SSSE3_SHA1_OBJ=sha1-ssse3.lo
310         AX_PROG_NASM
311         AC_SUBST([NASM], [$nasm])
312 else
313         SSSE3_SHA1_OBJ=
314 fi
315 AC_SUBST([SSSE3_SHA1_OBJ], [$SSSE3_SHA1_OBJ])
316
317 if test "x$ENABLE_SSSE3_SHA1" = "xyes"; then
318         WITH_LIBCRYPTO=no
319 else
320         AC_ARG_WITH([libcrypto],
321             AS_HELP_STRING([--without-libcrypto], [build in the SHA1 algorithm,
322                                         rather than use external libcrypto from
323                                         OpenSSL (default is autodetect)]),
324         [WITH_LIBCRYPTO=$withval],
325         [AC_CHECK_LIB([crypto], [SHA1],
326                      [WITH_LIBCRYPTO=yes],
327                      [AC_MSG_WARN([Cannot find libcrypto: using stand-alone SHA1 code instead of OpenSSL])
328                      WITH_LIBCRYPTO=no
329                      ])])
330 fi
331 AC_MSG_CHECKING([whether to use SHA1 function from system libcrypto])
332 AC_MSG_RESULT([$WITH_LIBCRYPTO])
333
334 if test "x$WITH_LIBCRYPTO" = "xyes" -a "x$ENABLE_SSSE3_SHA1" = "xno"; then
335         AC_DEFINE([WITH_LIBCRYPTO], [1], [Define to 1 if using libcrypto SHA1])
336         LIBCRYPTO_LDADD=`pkg-config --libs libcrypto 2>/dev/null`
337         if test $? -ne 0; then
338                 LIBCRYPTO_LDADD=-lcrypto;
339         fi
340         LIBCRYPTO_CFLAGS=`pkg-config --cflags libcrypto 2>/dev/null`
341 else
342         LIBCRYPTO_LDADD=
343         LIBCRYPTO_CFLAGS=
344 fi
345 AC_SUBST([LIBCRYPTO_LDADD], [$LIBCRYPTO_LDADD])
346 AC_SUBST([LIBCRYPTO_CFLAGS], [$LIBCRYPTO_CFLAGS])
347 AC_SUBST([SHA1_SOURCES], [$SHA1_SOURCES])
348
349 AC_OUTPUT