More build system cleanups
[wimlib] / configure.ac
1 AC_INIT([wimlib], [0.7.2], [ebiggers3@gmail.com])
2 AC_CONFIG_SRCDIR([src/wim.c])
3 AC_CONFIG_MACRO_DIR([m4])
4 AC_CONFIG_AUX_DIR([build-aux])
5 AM_INIT_AUTOMAKE([-Wall -Werror subdir-objects])
6 AC_C_BIGENDIAN
7 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
8 LT_INIT
9 AC_CONFIG_HEADERS([config.h])
10 AC_CONFIG_FILES([Makefile 
11                 doc/Doxyfile
12                 wimlib.pc
13                 doc/imagex.1
14                 doc/imagex-append.1
15                 doc/imagex-apply.1
16                 doc/imagex-capture.1
17                 doc/imagex-delete.1
18                 doc/imagex-dir.1
19                 doc/imagex-export.1
20                 doc/imagex-info.1
21                 doc/imagex-join.1
22                 doc/imagex-mount.1
23                 doc/imagex-mountrw.1
24                 doc/imagex-split.1
25                 doc/imagex-unmount.1
26                 doc/mkwinpeimg.1
27                 rpm/wimlib.spec
28                 archlinux/PKGBUILD
29                 ])
30 AC_PROG_CC
31 AM_PROG_CC_C_O
32
33
34 AM_ICONV
35 if test "x$am_cv_func_iconv" != "xyes"; then
36         AC_MSG_ERROR([Cannot find the iconv() function.
37         iconv() is used to convert between UTF-8 and UTF-16 encodings of WIM
38         filenames and XML data.  Wimlib cannot be compiled without it.  iconv()
39         is available in the latest version of glibc and sometimes in other
40         libraries.])
41 fi
42
43 AC_ARG_WITH(pkgconfigdir,
44             [  --with-pkgconfigdir=DIR      pkgconfig file in DIR @<:@LIBDIR/pkgconfig@:>@],
45             [pkgconfigdir=$withval],
46             [pkgconfigdir='${libdir}/pkgconfig'])
47 AC_SUBST(pkgconfigdir)
48
49 AC_CHECK_LIB([xml2], [xmlParseFile], [have_libxml=true],
50              [AC_MSG_ERROR(["cannot find libxml2"])])
51 LIBXML2_LDADD=`pkg-config libxml-2.0 --libs`
52 LIBXML2_CFLAGS=`pkg-config libxml-2.0 --cflags`
53 AC_SUBST([LIBXML2_LDADD], [$LIBXML2_LDADD])
54 AC_SUBST([LIBXML2_CFLAGS], [$LIBXML2_CFLAGS])
55
56 AC_MSG_CHECKING([whether to include debugging messages])
57 AC_ARG_ENABLE([debug], 
58         AS_HELP_STRING([--enable-debug], [include lots of debugging messages]),
59         [ENABLE_DEBUG=$enableval],
60         [ENABLE_DEBUG=no]
61         )
62 AC_MSG_RESULT([$ENABLE_DEBUG])
63 if test "x$ENABLE_DEBUG" = "xyes"; then
64         AC_DEFINE([ENABLE_DEBUG], [1], 
65                         [Define to 1 if including lots of debug messages.])
66 fi
67
68 AC_MSG_CHECKING([whether to include more debugging messages])
69 AC_ARG_ENABLE([more_debug], 
70         AS_HELP_STRING([--enable-more-debug], 
71                         [include even more debugging messages]),
72         [ENABLE_MORE_DEBUG=$enableval],
73         [ENABLE_MORE_DEBUG=no]
74         )
75 AC_MSG_RESULT([$ENABLE_MORE_DEBUG])
76 if test "x$ENABLE_MORE_DEBUG" = "xyes"; then
77         AC_DEFINE([ENABLE_MORE_DEBUG], [1], 
78                         [Define to 1 if including even more debug messages.])
79 fi
80
81 AC_MSG_CHECKING([whether to include error messages])
82 AC_ARG_ENABLE([error_messages], 
83         AS_HELP_STRING([--disable-error-messages], 
84                         [do not compile in error messsages]),
85         [ENABLE_ERROR_MESSAGES=$enableval],
86         [ENABLE_ERROR_MESSAGES=yes]
87         )
88 AC_MSG_RESULT([$ENABLE_ERROR_MESSAGES])
89 if test "x$ENABLE_ERROR_MESSAGES" = "xyes"; then
90         AC_DEFINE([ENABLE_ERROR_MESSAGES], [1], 
91                         [Define to 1 if including error messages])
92 fi
93
94 AC_MSG_CHECKING([whether to support custom memory allocation functions])
95 AC_ARG_ENABLE([custom_memory_allocator], 
96         AS_HELP_STRING([--disable-custom-memory-allocator], 
97                        [do not support the use of custom memory allocation
98                         functions]),
99         [ENABLE_CUSTOM_MEMORY_ALLOCATOR=$enableval],
100         [ENABLE_CUSTOM_MEMORY_ALLOCATOR=yes]
101         )
102 AC_MSG_RESULT([$ENABLE_CUSTOM_MEMORY_ALLOCATOR])
103 if test "x$ENABLE_CUSTOM_MEMORY_ALLOCATOR" = "xyes"; then
104         AC_DEFINE([ENABLE_CUSTOM_MEMORY_ALLOCATOR], [1], 
105                 [Define to 1 if supporting custom memory allocation functions])
106 fi
107
108 AC_MSG_CHECKING([whether to include assertions])
109 AC_ARG_ENABLE([assertions],
110         AS_HELP_STRING([--disable-assertions], [do not include assertions]),
111         [ENABLE_ASSERTIONS=$enableval],
112         [ENABLE_ASSERTIONS=yes]
113         )
114 AC_MSG_RESULT([$ENABLE_ASSERTIONS])
115 if test "x$ENABLE_ASSERTIONS" = "xyes"; then
116         AC_DEFINE([ENABLE_ASSERTIONS], [1], [Define to 1 if including assertions.])
117 fi
118
119
120 AC_MSG_CHECKING([whether to include compression verification])
121 AC_ARG_ENABLE([verify_compression],
122               AS_HELP_STRING([--disable-verify-compression], [disable
123                                 checking if blocks we compress can be correctly
124                                 decompressed]),
125         [ENABLE_VERIFY_COMPRESSION=$enableval],
126         [ENABLE_VERIFY_COMPRESSION=yes]
127         )
128 AC_MSG_RESULT([$ENABLE_VERIFY_COMPRESSION])
129 if test "x$ENABLE_VERIFY_COMPRESSION" = "xyes"; then
130         AC_DEFINE([ENABLE_VERIFY_COMPRESSION], [1], [Define to 1 to verify
131                    compressed data])
132 fi
133
134 AC_MSG_CHECKING([whether to include support for copying security data])
135 AC_ARG_ENABLE([security_data],
136               AS_HELP_STRING([--disable-security-data], [disable
137                                 the ability to retain the security data of
138                                 existing WIMs]),
139         [ENABLE_SECURITY_DATA=$enableval],
140         [ENABLE_SECURITY_DATA=yes]
141         )
142 AC_MSG_RESULT([$ENABLE_SECURITY_DATA])
143 if test "x$ENABLE_SECURITY_DATA" = "xyes"; then
144         AC_DEFINE([ENABLE_SECURITY_DATA], [1], [Define to 1 to enable support
145                    for copying security data])
146 fi
147
148 AC_MSG_CHECKING([whether to include support for mounting WIMs])
149 AC_ARG_WITH([fuse],
150                 AS_HELP_STRING([--without-fuse], [build without libfuse.  
151                                         This will disable the ability to mount 
152                                         WIM files.]),
153         [WITH_FUSE=$withval],
154         [WITH_FUSE=yes]
155         )
156 AC_MSG_RESULT([$WITH_FUSE])
157 if test "x$WITH_FUSE" = "xyes"; then
158         AC_DEFINE([WITH_FUSE], [1], [Define to 1 if using FUSE.])
159
160
161         AC_CHECK_LIB([fuse], [fuse_main_real], [have_fuse=true],
162                         [AC_MSG_ERROR([Cannot find libfuse.  
163         Without libfuse, WIMLIB cannot include support for mounting WIMs.  You
164         should either install libfuse, or configure with --without-fuse to
165         disable support for mounting WIMs.])
166         ])
167         AC_CHECK_LIB([rt], [mq_open], [have_posix_mq=true],
168                      [AC_MSG_ERROR([Cannot find librt for POSIX message queue
169         functions.  Without these functions, WIMLIB cannot include support for
170         mounting WIMs.  You should either update your C library to a recent
171         version of glibc, or configure with --without-fuse to disable support
172         for mounting WIMs.])
173         ])
174         LIBFUSE_LDADD="`pkg-config --libs fuse` -lrt"
175         LIBFUSE_CFLAGS="`pkg-config --cflags fuse`"
176 else
177         LIBFUSE_LDADD=
178         LIBFUSE_CFLAGS=
179 fi
180 AC_SUBST([LIBFUSE_LDADD], [$LIBFUSE_LDADD])
181 AC_SUBST([LIBFUSE_CFLAGS], [$LIBFUSE_CFLAGS])
182
183 AC_MSG_CHECKING([whether to use SSSE3-accelerated SHA1 ])
184 AC_ARG_ENABLE([ssse3-sha1],
185             AS_HELP_STRING([--enable-ssse3-sha1], [use assembly language implementation
186                                 of SHA1 from Intel, accelerated with vector
187                                 instructions (SSSE3-enabled CPU required)]),
188         [ENABLE_SSSE3_SHA1=$enableval],
189         [ENABLE_SSSE3_SHA1=no]
190         )
191         
192 AC_MSG_RESULT([$ENABLE_SSSE3_SHA1])
193 if test "x$ENABLE_SSSE3_SHA1" = "xyes"; then
194         AC_DEFINE([ENABLE_SSSE3_SHA1], [1], 
195                         [Define to 1 if using vectorized implementation of SHA1])
196         SSSE3_SHA1_OBJ=sha1-ssse3.lo
197         AX_PROG_NASM
198         AC_SUBST([NASM], [$nasm])
199 else
200         SSSE3_SHA1_OBJ=
201 fi
202 AC_SUBST([SSSE3_SHA1_OBJ], [$SSSE3_SHA1_OBJ])
203
204 if test "x$ENABLE_SSSE3_SHA1" = "xyes"; then
205         WITH_LIBCRYPTO=no
206 else
207         AC_ARG_WITH([libcrypto],
208             AS_HELP_STRING([--without-libcrypto], [build in the SHA1 algorithm,
209                                         rather than use external libcrypto from
210                                         OpenSSL (default is autodetect)]),
211         [WITH_LIBCRYPTO=$withval],
212         [AC_CHECK_LIB([crypto], [SHA1], 
213                      [WITH_LIBCRYPTO=yes],
214                      [AC_MSG_WARN([Cannot find libcrypto: using stand-alone SHA1 code instead of OpenSSL])
215                      WITH_LIBCRYPTO=no
216                      ])])
217 fi
218 AC_MSG_CHECKING([whether to use SHA1 function from system libcrypto])
219 AC_MSG_RESULT([$WITH_LIBCRYPTO])
220
221 if test "x$WITH_LIBCRYPTO" = "xyes" -a "x$ENABLE_SSSE3_SHA1" = "xno"; then
222         AC_DEFINE([WITH_LIBCRYPTO], [1], [Define to 1 if using libcrypto SHA1])
223         LIBCRYPTO_LDADD=`pkg-config --libs libcrypto 2>/dev/null`
224         if test $? -ne 0; then
225                 LIBCRYPTO_LDADD=-lcrypto;
226         fi
227         LIBCRYPTO_CFLAGS=`pkg-config --cflags libcrypto 2>/dev/null`
228 else
229         LIBCRYPTO_LDADD=
230         LIBCRYPTO_CFLAGS=
231 fi
232 AC_SUBST([LIBCRYPTO_LDADD], [$LIBCRYPTO_LDADD])
233 AC_SUBST([LIBCRYPTO_CFLAGS], [$LIBCRYPTO_CFLAGS])
234 AC_SUBST([SHA1_SOURCES], [$SHA1_SOURCES])
235
236 AC_OUTPUT