wimlib.net Git - wimlib/blob - configure.ac

   1 AC_INIT([wimlib], [1.1.0], [ebiggers3@gmail.com])
   2 AC_CONFIG_SRCDIR([src/wim.c])
   3 AC_CONFIG_MACRO_DIR([m4])
   4 AC_CONFIG_AUX_DIR([build-aux])
   5 AM_INIT_AUTOMAKE([-Wall -Werror subdir-objects])
   6 AC_C_BIGENDIAN
   7 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
   8 LT_INIT
   9 AC_CONFIG_HEADERS([config.h])
  10 AC_CONFIG_FILES([Makefile
  11                 doc/Doxyfile
  12                 wimlib.pc
  13                 doc/imagex.1
  14                 doc/imagex-append.1
  15                 doc/imagex-apply.1
  16                 doc/imagex-capture.1
  17                 doc/imagex-delete.1
  18                 doc/imagex-dir.1
  19                 doc/imagex-export.1
  20                 doc/imagex-info.1
  21                 doc/imagex-join.1
  22                 doc/imagex-mount.1
  23                 doc/imagex-mountrw.1
  24                 doc/imagex-split.1
  25                 doc/imagex-unmount.1
  26                 doc/mkwinpeimg.1
  27                 ])
  28 AC_PROG_CC
  29 AM_PROG_CC_C_O
  30
  31 AC_CHECK_FUNCS([utimensat lutimes utime])
  32 AC_CHECK_HEADERS([endian.h byteswap.h sys/byteorder.h sys/endian.h \
  33                   sys/param.h machine/endian.h alloca.h stdlib.h stdarg.h \
  34                   errno.h attr/xattr.h utime.h])
  35
  36
  37 AM_ICONV
  38 if test "x$am_cv_func_iconv" != "xyes"; then
  39         AC_MSG_ERROR([Cannot find the iconv() function.
  40         iconv() is used to convert between UTF-8 and UTF-16 encodings of WIM
  41         filenames and XML data.  Wimlib cannot be compiled without it.  iconv()
  42         is available in the latest version of glibc and sometimes in other
  43         libraries.])
  44 fi
  45
  46
  47 AC_ARG_WITH(pkgconfigdir,
  48             [  --with-pkgconfigdir=DIR      pkgconfig file in DIR @<:@LIBDIR/pkgconfig@:>@],
  49             [pkgconfigdir=$withval],
  50             [pkgconfigdir='${libdir}/pkgconfig'])
  51 AC_SUBST(pkgconfigdir)
  52
  53 AC_CHECK_LIB([xml2], [xmlParseFile], [have_libxml=true],
  54              [AC_MSG_ERROR(["cannot find libxml2"])])
  55 LIBXML2_LDADD=`pkg-config libxml-2.0 --libs`
  56 LIBXML2_CFLAGS=`pkg-config libxml-2.0 --cflags`
  57 AC_SUBST([LIBXML2_LDADD], [$LIBXML2_LDADD])
  58 AC_SUBST([LIBXML2_CFLAGS], [$LIBXML2_CFLAGS])
  59
  60 AC_MSG_CHECKING([whether to include debugging messages])
  61 AC_ARG_ENABLE([debug],
  62         AS_HELP_STRING([--enable-debug], [include lots of debugging messages]),
  63         [ENABLE_DEBUG=$enableval],
  64         [ENABLE_DEBUG=no]
  65         )
  66 AC_MSG_RESULT([$ENABLE_DEBUG])
  67 if test "x$ENABLE_DEBUG" = "xyes"; then
  68         AC_DEFINE([ENABLE_DEBUG], [1],
  69                         [Define to 1 if including lots of debug messages.])
  70 fi
  71
  72 AC_MSG_CHECKING([whether to include more debugging messages])
  73 AC_ARG_ENABLE([more_debug],
  74         AS_HELP_STRING([--enable-more-debug],
  75                         [include even more debugging messages]),
  76         [ENABLE_MORE_DEBUG=$enableval],
  77         [ENABLE_MORE_DEBUG=no]
  78         )
  79 AC_MSG_RESULT([$ENABLE_MORE_DEBUG])
  80 if test "x$ENABLE_MORE_DEBUG" = "xyes"; then
  81         AC_DEFINE([ENABLE_MORE_DEBUG], [1],
  82                         [Define to 1 if including even more debug messages.])
  83 fi
  84
  85 AC_MSG_CHECKING([whether to include error messages])
  86 AC_ARG_ENABLE([error_messages],
  87         AS_HELP_STRING([--disable-error-messages],
  88                         [do not compile in error messsages]),
  89         [ENABLE_ERROR_MESSAGES=$enableval],
  90         [ENABLE_ERROR_MESSAGES=yes]
  91         )
  92 AC_MSG_RESULT([$ENABLE_ERROR_MESSAGES])
  93 if test "x$ENABLE_ERROR_MESSAGES" = "xyes"; then
  94         AC_DEFINE([ENABLE_ERROR_MESSAGES], [1],
  95                         [Define to 1 if including error messages])
  96 fi
  97
  98 AC_MSG_CHECKING([whether to support custom memory allocation functions])
  99 AC_ARG_ENABLE([custom_memory_allocator],
 100         AS_HELP_STRING([--disable-custom-memory-allocator],
 101                        [do not support the use of custom memory allocation
 102                         functions]),
 103         [ENABLE_CUSTOM_MEMORY_ALLOCATOR=$enableval],
 104         [ENABLE_CUSTOM_MEMORY_ALLOCATOR=yes]
 105         )
 106 AC_MSG_RESULT([$ENABLE_CUSTOM_MEMORY_ALLOCATOR])
 107 if test "x$ENABLE_CUSTOM_MEMORY_ALLOCATOR" = "xyes"; then
 108         AC_DEFINE([ENABLE_CUSTOM_MEMORY_ALLOCATOR], [1],
 109                 [Define to 1 if supporting custom memory allocation functions])
 110 fi
 111
 112 AC_MSG_CHECKING([whether to include assertions])
 113 AC_ARG_ENABLE([assertions],
 114         AS_HELP_STRING([--disable-assertions], [do not include assertions]),
 115         [ENABLE_ASSERTIONS=$enableval],
 116         [ENABLE_ASSERTIONS=yes]
 117         )
 118 AC_MSG_RESULT([$ENABLE_ASSERTIONS])
 119 if test "x$ENABLE_ASSERTIONS" = "xyes"; then
 120         AC_DEFINE([ENABLE_ASSERTIONS], [1], [Define to 1 if including assertions.])
 121 fi
 122
 123
 124 AC_MSG_CHECKING([whether to include compression verification])
 125 AC_ARG_ENABLE([verify_compression],
 126               AS_HELP_STRING([--disable-verify-compression], [disable
 127                                 checking if blocks we compress can be correctly
 128                                 decompressed]),
 129         [ENABLE_VERIFY_COMPRESSION=$enableval],
 130         [ENABLE_VERIFY_COMPRESSION=yes]
 131         )
 132 AC_MSG_RESULT([$ENABLE_VERIFY_COMPRESSION])
 133 if test "x$ENABLE_VERIFY_COMPRESSION" = "xyes"; then
 134         AC_DEFINE([ENABLE_VERIFY_COMPRESSION], [1], [Define to 1 to verify
 135                    compressed data])
 136 fi
 137
 138 AC_MSG_CHECKING([whether to include support for ntfs-3g])
 139 AC_ARG_WITH([ntfs-3g],
 140               AS_HELP_STRING([--without-ntfs-3g], [build without NTFS-3g.
 141                               This will disable the ability to use NTFS-specific
 142                               information when capturing or applying WIMs to a
 143                               NTFS filesystem.]),
 144         [WITH_NTFS_3G=$withval],
 145         [WITH_NTFS_3G=yes]
 146         )
 147 AC_MSG_RESULT([$WITH_NTFS_3G])
 148 if test "x$WITH_NTFS_3G" = "xyes"; then
 149         AC_DEFINE([WITH_NTFS_3G], [1], [Define to 1 to enable support for
 150                    NTFS-specific information])
 151
 152         AC_CHECK_LIB([ntfs-3g], [ntfs_xattr_system_setxattr], [],
 153                         [AC_MSG_ERROR([Cannot find libntfs-3g version 2011-4-12
 154         or later. Without libntfs-3g, wimlib cannot include support for
 155         capturing and applying WIMs on NTFS filesystems while preserving
 156         NTFS-specific data such as security descriptors and alternate data
 157         streams.  You should either install libntfs-3g, or configure with
 158         --without-ntfs-3g to disable support for these NTFS-specific
 159         features.])])
 160         LIBNTFS_3G_LDADD="`pkg-config --libs libntfs-3g`"
 161         LIBNTFS_3G_CFLAGS="`pkg-config --cflags libntfs-3g`"
 162 else
 163         LIBNTFS_3G_LDADD=
 164         LIBNTFS_3G_CFLAGS=
 165 fi
 166 AM_CONDITIONAL([WITH_NTFS_3G], [test "x$WITH_NTFS_3G" = "xyes"])
 167
 168 AC_SUBST([LIBNTFS_3G_LDADD], [$LIBNTFS_3G_LDADD])
 169 AC_SUBST([LIBNTFS_3G_CFLAGS], [$LIBNTFS_3G_CFLAGS])
 170
 171 AC_MSG_CHECKING([whether to include support for mounting WIMs])
 172 AC_ARG_WITH([fuse],
 173                 AS_HELP_STRING([--without-fuse], [build without libfuse.
 174                                         This will disable the ability to mount
 175                                         WIM files.]),
 176         [WITH_FUSE=$withval],
 177         [WITH_FUSE=yes]
 178         )
 179 AC_MSG_RESULT([$WITH_FUSE])
 180 if test "x$WITH_FUSE" = "xyes"; then
 181         AC_DEFINE([WITH_FUSE], [1], [Define to 1 if using FUSE.])
 182
 183
 184         AC_CHECK_LIB([fuse], [fuse_main_real], [have_fuse=true],
 185                         [AC_MSG_ERROR([Cannot find libfuse.
 186         Without libfuse, wimlib cannot include support for mounting WIMs.  You
 187         should either install libfuse, or configure with --without-fuse to
 188         disable support for mounting WIMs.])
 189         ])
 190         AC_CHECK_LIB([rt], [mq_open], [have_posix_mq=true],
 191                      [AC_MSG_ERROR([Cannot find librt for POSIX message queue
 192         functions.  Without these functions, wimlib cannot include support for
 193         mounting WIMs.  You should either update your C library to a recent
 194         version of glibc, or configure with --without-fuse to disable support
 195         for mounting WIMs.])
 196         ])
 197         LIBFUSE_LDADD="`pkg-config --libs fuse` -lrt"
 198         LIBFUSE_CFLAGS="`pkg-config --cflags fuse`"
 199 else
 200         LIBFUSE_LDADD=
 201         LIBFUSE_CFLAGS=
 202 fi
 203 AM_CONDITIONAL([WITH_FUSE], [test "x$WITH_FUSE" = "xyes"])
 204 AC_SUBST([LIBFUSE_LDADD], [$LIBFUSE_LDADD])
 205 AC_SUBST([LIBFUSE_CFLAGS], [$LIBFUSE_CFLAGS])
 206
 207 ENABLE_XATTR=no
 208 AC_ARG_ENABLE([xattr],
 209         [AS_HELP_STRING([--enable-xattr], [Enable the xattr interface to access WIM
 210                         alternate data streams (default: autodetect)])],
 211         [ENABLE_XATTR=$enableval],
 212         [AC_CHECK_FUNC([setxattr],
 213                 [AC_CHECK_HEADER([attr/xattr.h],
 214                         [ENABLE_XATTR=yes],
 215                         [AC_MSG_WARN([Cannot find the "attr/xattr.h" header.  You will not be
 216                          able to use the xattr interface to access WIM alternate data
 217                          streams.])])],
 218                 [AC_MSG_WARN([Cannot find the setxattr() function.  You will not be
 219                  able to use the xattr interface to access WIM alternate data
 220                  streams.])])])
 221
 222 if test "x$ENABLE_XATTR" = "xyes"; then
 223         AC_DEFINE([ENABLE_XATTR], [1], [Define to 1 if using the xattr
 224                         interface to WIM alternate data streams])
 225 fi
 226
 227 AC_MSG_CHECKING([whether to use SSSE3-accelerated SHA1 ])
 228 AC_ARG_ENABLE([ssse3-sha1],
 229             AS_HELP_STRING([--enable-ssse3-sha1], [use assembly language implementation
 230                                 of SHA1 from Intel, accelerated with vector
 231                                 instructions (SSSE3-enabled CPU required)]),
 232         [ENABLE_SSSE3_SHA1=$enableval],
 233         [ENABLE_SSSE3_SHA1=no]
 234         )
 235
 236 AC_MSG_RESULT([$ENABLE_SSSE3_SHA1])
 237 if test "x$ENABLE_SSSE3_SHA1" = "xyes"; then
 238         AC_DEFINE([ENABLE_SSSE3_SHA1], [1],
 239                         [Define to 1 if using vectorized implementation of SHA1])
 240         SSSE3_SHA1_OBJ=sha1-ssse3.lo
 241         AX_PROG_NASM
 242         AC_SUBST([NASM], [$nasm])
 243 else
 244         SSSE3_SHA1_OBJ=
 245 fi
 246 AC_SUBST([SSSE3_SHA1_OBJ], [$SSSE3_SHA1_OBJ])
 247
 248 if test "x$ENABLE_SSSE3_SHA1" = "xyes"; then
 249         WITH_LIBCRYPTO=no
 250 else
 251         AC_ARG_WITH([libcrypto],
 252             AS_HELP_STRING([--without-libcrypto], [build in the SHA1 algorithm,
 253                                         rather than use external libcrypto from
 254                                         OpenSSL (default is autodetect)]),
 255         [WITH_LIBCRYPTO=$withval],
 256         [AC_CHECK_LIB([crypto], [SHA1],
 257                      [WITH_LIBCRYPTO=yes],
 258                      [AC_MSG_WARN([Cannot find libcrypto: using stand-alone SHA1 code instead of OpenSSL])
 259                      WITH_LIBCRYPTO=no
 260                      ])])
 261 fi
 262 AC_MSG_CHECKING([whether to use SHA1 function from system libcrypto])
 263 AC_MSG_RESULT([$WITH_LIBCRYPTO])
 264
 265 if test "x$WITH_LIBCRYPTO" = "xyes" -a "x$ENABLE_SSSE3_SHA1" = "xno"; then
 266         AC_DEFINE([WITH_LIBCRYPTO], [1], [Define to 1 if using libcrypto SHA1])
 267         LIBCRYPTO_LDADD=`pkg-config --libs libcrypto 2>/dev/null`
 268         if test $? -ne 0; then
 269                 LIBCRYPTO_LDADD=-lcrypto;
 270         fi
 271         LIBCRYPTO_CFLAGS=`pkg-config --cflags libcrypto 2>/dev/null`
 272 else
 273         LIBCRYPTO_LDADD=
 274         LIBCRYPTO_CFLAGS=
 275 fi
 276 AC_SUBST([LIBCRYPTO_LDADD], [$LIBCRYPTO_LDADD])
 277 AC_SUBST([LIBCRYPTO_CFLAGS], [$LIBCRYPTO_CFLAGS])
 278 AC_SUBST([SHA1_SOURCES], [$SHA1_SOURCES])
 279
 280 AC_OUTPUT