c4f55e64cae0ed886289ebc1b8bc07ac2199b1bf
[wimlib] / archlinux / PKGBUILD
1 # Maintainer:  Eric Biggers <ebiggers3 at gmail dot com>
2
3 pkgname=wimlib
4 pkgver=1.12.0
5 pkgrel=1
6 pkgdesc="A library and program to extract, create, and modify WIM files"
7 arch=("i686" "x86_64")
8 url="https://wimlib.net"
9 license=("custom")
10 depends=("openssl" "fuse" "libxml2" "ntfs-3g")
11 checkdepends=("attr")
12 optdepends=("cdrkit: for making ISO image of Windows PE"
13         "mtools: for making disk image of Windows PE"
14         "syslinux: for making disk image of Windows PE"
15         "cabextract: for extracting Windows PE from the WAIK")
16 source=("https://wimlib.net/downloads/$pkgname-$pkgver.tar.gz")
17
18 build() {
19         cd "$pkgname-$pkgver"
20         ./configure --with-libcrypto --with-fuse --with-ntfs-3g --prefix=/usr
21         make
22 }
23
24 check() {
25         cd "$pkgname-$pkgver"
26         make check
27 }
28
29 package() {
30         cd "$pkgname-$pkgver"
31         make DESTDIR="$pkgdir" install
32         for file in NEWS README; do
33                 install -Dm644 $file "$pkgdir/usr/share/doc/$pkgname/$file"
34         done
35         for file in COPYING*; do
36                 install -Dm644 $file "$pkgdir/usr/share/licenses/$pkgname/$file"
37         done
38 }